ANSYS中的时谐电场

一般，在我们的印象里，电场要么为“静电场”，要么为“恒定电场”。这两类在ANSYS中一般分别可以采用Plane121和Plane68单元来解决(仅以2D为例)。

实际上，上述求解相当于“电路”中纯“电容”或“电阻”电路，但有时如果“电容”和“电阻”效应相当时，如何解决呢？如一块受潮的绝缘介质，在交流条件下其中电场如何分布呢？

这就是——时谐电场(Harmonic Electric Field)。

经过本人试验，得到如下结论：

1 时谐电场版本：

时谐电场为ANSYS10.0推出的新功能，ANSYS8.0之前不具备。

2 时谐电场单元：

Plane121, Plane230。本人仅试验2D条件下这两个单元，也许其它单元也有此功能，但未验证，主要需要查看单元所要求的“材料属性”。

3 特点：

   体现了“静电场”的电容特性，“恒定电流”场的电流特性。所以最后可以求电容、损耗、导纳这一类问题。

4 算例程序：

    一个平行版电容导纳的求解问题。

! Part 1: Initializing data about the system;

  a=9.e-2                        ! radius, m

  d=0.1e-2                       ! thickness, m

  epsr=1143                      ! relative permittivity

  tand=0.0105                    ! loss tangent

  Vo=50                         ! voltage amplitude, V

  f1=0                           ! begin frequency, Hz

  f2=1E6                        ! end frequency, Hz

  eps0=8.854e-12                 ! free space permittivity, F/m

  Pi=acos(-1)

  C=epsr*eps0*Pi*a**2/d          ! capacitance, F

  P2d=Pi*f2*Vo**2*C*tand         ! power dissipation at freq. f2, Watt

! Part 2: Creating and meshing model;

  /PREP7

  et,1,PLANE230,,,1              ! axisymmetric electric element

  !emunit,epzro,eps0              ! specify free-space permittivity

  mp,perx,1,epsr                 ! electric material properties

  mp,lsst,1,tand

  rect,,a,,d                     ! model and mesh

  esize,d/2

  Amesh,1

! Part 3: Boundary conditions and loads

  nsel,s,loc,y,0

  cp,1,volt,all                  ! define bottom electrode

  *get,n_grd,node,0,num,min      ! get master node on bottom electrode

  nsel,s,loc,y,d

  cp,2,volt,all                  ! top electrode

  *get,n_load,node,0,num,min     ! get master node on top electrode

  nsel,all

  d,n_grd,volt,0                 ! ground bottom electrode

  d,n_load,volt,Vo               ! apply voltage load to top electrode

  Finish

! Part 4: Solving the harmonic electric field;

  /solu

  antype,harm                    ! harmonic analysis

  harfrq,f1,f2                   ! frequency range

  nsubs,10                       ! number of substeps

  outres,all,all                 ! write all solution items to the result file

  kbc,1                          ! stepped load

  solve

  Finish

! Part 5；Postprocedures;

  /post1                        

  /com,Calculate power dissipation at frequency = %f2%, Hz

  set,last                     ! read last data set

  Etab,jh,jheat                ! fill etable with Joule heat rates per unit volume

  Etab,vol,volu                ! fill etable with element volumes

  Smult,dpower,jh,vol          ! fill etable with element Joule heat rates

  Ssum                           ! sum element Joule heat rates

  /com,Expected power dissipation = %P2d%, Watt

  Finish

! Part 6: TimeHist___postprocedure

  /post26

  RForce,2,n_load,amps         ! reaction current I

  Prod,3,2,,,Y_ANSYS,,,1/Vo    ! Y_ansys = I/V

  Prod,4,1,,,,,,2*Pi*C           ! 2*Pi*f*C

  cfact,tand,,,1

  add,5,4,4,,Y_TARGET            ! Y_target = 2*Pi*f*C*(tand+j)

  prcplx,1

  prvar,Y_ANSYS,Y_TARGET

  Finish