ANSYS压电双晶片梁致动和传感分析实例

ANSYS10.0帮助文件中，Relese10.0 documentation for ANSYS 7.13 对压电双晶片梁的作动、传感模式进行了仿真分析。

当作为 作动元件时在极性相反的压电层的厚度方向施加电场，由于正压电效应，一层收缩另一层伸长，结果导致双极性晶片弯曲变形，其端部在Y方向产生位移。本例通过再上表面施加100V的电压。

根据 Uy = -3(d₃₁)(V)(L)²/8(H)²

端部产生-33um的挠度。 通过ANSYS仿真计算 得到挠度为-32.9 um.

传感元件时 让其端度产生1mm的大变形 仿真计算 电极上产生电压。

通过对例子分析 APDL程序理解消化

/batch,list
/title, Static Analysis of a Piezoelectric Bimorph Beam
/nopr
/com,
/PREP7

! 几何参数
!
L=100e-3 ! 长度, m
H=0.5e-3 ! 压电单层厚度, m
!
! 载荷
!
V=100 ! 电极电压, Volt
Uy=10.e-3 ! 端部挠度, m
!
! PVDF 材料特性
!
E1=2.0e9 ! 杨氏模量, N/m^2
NU12=0.29 ! 泊松比
G12=0.775e9 ! 剪切模量, N/m^2
d31=2.2e-11 ! 压电应变常数, C/N
d32=0.3e-11
d33=-3.0e-11
ept33=12 ! 介电常数
!
! 双压电晶片梁有限元模型
!
local,11 ! 建立局部坐标系 下部 +Y方向
local,12,,,,,180 #p#分页标题#e#! 建立局部坐标系 上部 -Y方向
csys,11 ! 激活 局部坐标系11
rect,0,L,-H,0 ! 建立 底层面
rect,0,L, 0,H ! 建立 上层面
aglue,all ! 胶合 上下层
esize,H ! 确定 单元尺寸
!
et,1,PLANE223,1001,,0 ! 选定plane223单元, 1001 压电状态
! 初始形变为0

tb,ANEL,1,,,1 ! 建立弹性柔顺系数矩阵
tbda,1,1/E1,-NU12/E1,-NU12/E1
tbda,7,1/E1,-NU12/E1
tbda,12,1/E1
tbda,16,1/G12

tb,PIEZ,1,,,1 ! 建立压电应变系数矩阵
tbda,2,d31
tbda,5,d33
tbda,8,d32

tb,DPER,1,,,1 ! 建立介电应力常数矩阵
tbdata,1,ept33,ept33

tblist,all ! 显示所有材料特性矩阵

! -------------------------------------------------------------------------
! 选择另外单元 plane13 及其材料特性的输入
!
!et,1,PLANE13,7,,2 ! 选用二维压电单元, 平面应力状态
!
!mp,EX,1,E1 ! 弹性系数
!mp,NUXY,1,NU12#p#分页标题#e#
!mp,GXY,1,G12
!
!tb,PIEZ,1 ! 压电应力常数矩阵
!tbda,2,0.2876e-1
!tbda,5,-0.5186e-1
!tbda,8,-0.7014e-3
!
!mp,PERX,1,11.75 ! 介电应变常数矩阵
! -------------------------------------------------------------------------
type,1 $ esys,11
amesh,1 ! 划分下层网格
type,1 $ esys,12
amesh,3 ! 划分上层网格
!
nsel,s,loc,x,L
*get,ntip,node,0,num,min ! 获得梁端部 控制点坐标 (顶端最下方点)
!
nelec = 10 ! 上部电极个数
*dim,ntop,array,nelec
l1 = 0 ! 电极初始位置
l2 = L/nelec
*do,i,1,nelec ! 定义上层面电极
nsel,s,loc,y,H
nsel,r,loc,x,l1,l2
cp,i,volt,all !定义处于电极上所有点耦合自由度
*get,ntop(i),node,0,num,min !获得的电极 上控制节点 号
l1 = l2 + H/10 !更新电极位置
l2 = l2 + L/nelec
*enddo
nsel,s,loc,y,-H ! 定义下层电极
d,all,volt,0 #p#分页标题#e#! 底部电极 电压为零
nsel,s,loc,x,0 ! 限制 梁的最左端 自由度
d,all,ux,0,,,,uy
nsel,all
fini
/SOLU ! 作动器 仿真
antype,static ! 静态分析
*do,i,1,nelec
d,ntop(i),volt,V ! 对上方电极进行加压
*enddo
solve
Uy_an = -3*d31*V*L**2/(8*H**2) ! 理论解
/com,
/com, Actuator mode results:
/com, - Calculated tip displacement Uy = %uy(ntip)% (m)
/com, - Theoretical solution Uy = %Uy_an% (m)
fini
/SOLU ! 传感 仿真
antype,static,new
*do,i,1,nelec
ddele,ntop(i),volt ! 删除所加的电极 电压
*enddo
d,ntip,uy,Uy ! 在梁的端部作用位移
nlgeom,on ! 打开 大应变 效果
nsubs,2 ! Set number of substeps
cnvtol,F,1.e-3,1.e-3 ! 设置 F得 收敛值
cnvtol,CHRG,1.e-8,1.e-3 ! 设置 电荷 收敛值
!cnvtol,AMPS,1.e-8,1.e-3 !如选择 plane13单元 设置参数AMPS
solve
fini
/POST1
/com,
/com, Sensor mode results:
*do,i,1,nelec
/com, - Electrode %i% Voltage = %volt(ntop(i))% (Volt)
*enddo
/com,
/view,,1,,1 ! 设置 观察方位
/dscale,1,1 ! 设置 刻度
pldisp,1 #p#分页标题#e#! 显示 变形前后 的形状
path,position,2,,100 ! 设置 路径 名称及参数设置
ppath,1,,0,H ! 定义路径 沿着晶片 的上边沿
ppath,2,,L,H
pdef,Volt,volt,,noav ! 在定义路径上映射电压数据
pdef,Uy,u,y ! 在定义路径上映射y方向的位移数据
/axlab,x, Position (m) ! 设置 X轴 标签 为Position (m)
/axlab,y, Electrode Voltage (Volt)!设置 Y轴 标签为 Electrode Voltage (Volt)
plpath,Volt ! 显示路径上 电压
/axlab,y, Beam Deflection (m)
plpath,Uy ! 显示路径上的变形
pasave
fini