ANSYS的混凝土钢筋模型建立

本文介绍了ANSYS中建立混凝土钢筋模型的相关内容。

　　!一受均布荷载的简支梁，跨度为3000mm,截面为100x200mm，配有两根钢筋，承受的均布载荷为0.04N/mm*mm。命令中采用了1/4模型，材料参数详见命令中。由于选择时采用的是实体号而不是坐标，可能在有些系统上会受到影响，各位注意。

　　!钢筋混凝土简支梁分析

　　/COM, Structural

　　!----------定义单元及材料等---------------------

　　/PREP7

　　et,1,link8 !定义link8单元

　　et,2,solid65 !定义solid65单元

　　keyopt,2,7,1

　　r,1,314 !定义link8单元的面积

　　r,2 !定义solid65的实常数号

　　mp,ex,1,2e5 !定义link8单元的弹性模量

　　mp,prxy,1,0.3 !定义link8单元的泊松系数

　　mp,ex,2,4e4 !定义solid65单元的弹性模量

　　mp,prxy,2,0.3 !定义solid65单元的泊松系数

　　tb,concr,2 !定义2号为混凝土

　　tbdata,,0.9,1,1.8,50 !定义混凝土的c1,c2,Rl,Ra

　　!----------建立几何模型-------------------------

　　blc4, , ,50,200,1500 !定义梁体

　　/view,1,1,1,1 !定义ISO查看

　　/ang,1

　　vplot !绘制梁体

　　kwpave,5 !工作平面移动到关键点5

　　wpoff,25 !工作平面移动25mm

　　wprot,0,0,90 !工作平面旋转

　　vsbw,1 !分割梁体

　　wpoff,0,40 !工作平面移动40mm

　　wprot,0,90 !工作平面旋转

　　vsbw,all !分割梁体

　　wpoff,300 !再将梁体分割为三个区域

　　wprot,0,0,90 !(原为控制单元密度而设)

　　vsbw,all

　　wpoff,0,0,900

　　vsbw,all

　　wpstyl !关闭工作平面显示

　　nummrg,all !整理编号

　　numcmp,all

　　!------------划分单元网格---------------------------

　　lsel,s,,,41,57,16 !定义line41,line57为新的选择集

　　lsel,a,,,9 !定义line9也在选择集中

　　latt,1,1,1 !定义选择集的属性

　　lesize,9,,,20,,,,,1 !将line9划分为20个单元

　　lesize,41,,,20,,,,,1 !将line41划分为20个单元

　　lesize,57,,,60,,,,,1 !将line57划分为60个单元

　　lmesh,all !对线划分单元

　　!-------------

　　allsel,all !新的选择集为所有的实体

　　vsel,s,,,all !定义所有体为选择集

　　vatt,2,2,2 !定义选择集的属性

　　lesize,22,,,2,,,,,0 !定义体线的单元数以控制体单元

　　lesize,23,,,2,,,,,0

　　lesize,33,,,2,,,,,0

　　lesize,28,,,4,,,,,0

　　mshape,0,3d !将体划分单元的形状定位HEX

　　mshkey,1 !采用MAPPED划分器

　　vmesh,all !对体进行划分单元

　　finish

　　!--------------定义约束及荷载-------------------------

　　/solu

　　asel,s,,,2,22,20

　　asel,a,,,14,17,3

　　da,all,uy !对支撑端面施加Uy方向约束

　　asel,s,,,3,23,20

　　asel,a,,,15,19,4

　　da,all,uz !对正对称面施加Uz方向约束

　　asel,s,,,32,36,4

　　asel,a,,,50,52,2

　　asel,a,,,41,43,2

　　da,all,ux !对侧对称面施加Ux方向约束

　　asel,s,,,21,27,6

　　asel,a,,,42,46,4

　　asel,a,,,35,51,16

　　sfa,all,1,pres,0.04 !对顶面施加面荷载(N/mm*mm)

　　allsel,all

　　!--------------定义非线性分析选项--------------------

　　cnvtol,f,,0.05,2 !定义收敛条件,使用缺省的VALUE

　　nsubst,25 !定义子步数

　　outres,all,all !输出每一子步的结果

　　autots,1 !打开自动时间步控制

　　lnsrch,1 !打开线性搜索

　　ncnv,2 !如果不收敛时结束而不退出

　　neqit,50 !每一子步中方程的迭代次数限值

　　pred,on !打开预测器

　　time,50 !定义时间

　　solve !求解

　　!--------------进入后处理过程-----------------------

　　finish

　　/post1

　　pldisp,0 !绘制变形图(缺省为最后一步的)

　　etable,sig,ls,1 !定义应力表

　　plls,sigi,sigi,1 !绘制上述应力

　　plnsol,s,z,0,1 !绘制Z方向的应力

　　/device,vector,on